/* Molested version of output from 'ld --verbose' */

SEARCH_DIR("/usr/i486-linux-gnu/lib32"); SEARCH_DIR("/usr/local/lib32"); SEARCH_DIR("/lib32"); SEARCH_DIR("/usr/lib32"); SEARCH_DIR("/usr/i486-linux-gnu/lib"); SEARCH_DIR("/usr/local/lib"); SEARCH_DIR("/lib"); SEARCH_DIR("/usr/lib");
OUTPUT_FORMAT("elf32-i386", "elf32-i386",  "elf32-i386")
OUTPUT_ARCH(i386)

ENTRY(__tinker_start)

PHDRS {
	interp PT_INTERP ;
	text PT_LOAD FILEHDR PHDRS ;
	dynamic PT_DYNAMIC ;
}

SECTIONS {
	PROVIDE (__executable_start = 0x08048000); . = 0x08048000 + SIZEOF_HEADERS;
	.interp  : { *(.interp) } :text :interp
	.text  : { *(.text .stub .text.* .gnu.linkonce.t.*) } :text
	.rodata  : { *(.rodata) } :text
	.data  : { *(.rodata .rodata.* .gnu.linkonce.r.* .rodata1) *(.data .data.* .gnu.linkonce.d.* .data1) } :text
	.dynstr  : { *(.dynstr) } :text
	.dynamic  : { *(.dynamic) } :text :dynamic 			/* this is placed at the end of the file as it gets shortened post build */
	.dynsym  : { *(.dynsym) } :text 								/* this section is not used and is removed post build */
	.bss  : { *(.bss .bss.* .gnu.linkonce.b.*) *(COMMON) } :text
	
	/DISCARD/ : { *(.note.GNU-stack) *(.gnu_debuglink) *(.comment) *(.gnu.warning) *(.gnu_version) *(.gnu_version_r) *(.got)  *(.got_plt) }
}